// Copyright (C) 2017 The Qt Company Ltd.
// SPDX-License-Identifier: LicenseRef-Qt-Commercial OR LGPL-3.0-only OR GPL-2.0-only OR GPL-3.0-only
// Qt-Security score:significant reason:default

import QtQuick
import QtQuick.Templates as T
import QtQuick.Controls.impl

T.MenuBarItem {
    id: control

    implicitWidth: Math.max(implicitBackgroundWidth + leftInset + rightInset,
                            implicitContentWidth + leftPadding + rightPadding)
    implicitHeight: Math.max(implicitBackgroundHeight + topInset + bottomInset,
                             implicitContentHeight + topPadding + bottomPadding,
                             implicitIndicatorHeight + topPadding + bottomPadding)

    spacing: 6
    padding: 6
    leftPadding: 12
    rightPadding: 16

    icon.width: 24
    icon.height: 24

    contentItem: IconLabel {
        spacing: control.spacing
        mirrored: control.mirrored
        display: control.display
        alignment: Qt.AlignLeft

        icon: control.icon
        text: control.text
        font: control.font
        defaultIconColor: control.palette.buttonText
        color: defaultIconColor
    }

    background: Rectangle {
        implicitWidth: 40
        implicitHeight: 40
        color: control.down || control.highlighted ? control.palette.mid : "transparent"
        border.color: control.palette.dark
        border.width: Qt.styleHints.accessibility.contrastPreference === Qt.HighContrast &&
                      control.highlighted ? 1 : 0
    }
}
